(HN)CO(CO)NH experiment

;hncocogp3d1 (19/01/2014)
;avance-version (12/01/11)
;(HN)CO(CO)NH
;3D sequence with
;   inverse correlation for triple resonance using multiple
;      inept transfer steps and C-C MOCCA-XY16 spinlock
;
;      F1(H) -> F3(N) -> F2(C=O,t1) -> F2(C=O, TOCSY)
;                                   -> F3(N,t2) -> F1(H,t3)
;
;on/off resonance Ca and C=O pulses using shaped pulse
;phase sensitive (t1)
;phase sensitive using Echo/Antiecho gradient selection (t2)
;using semi-constant time in t1 for high resolution in IDPs
;using semi-constant time in t2 for high resolution in IDPs
;(use parameterset HNCOCOGP3D)
;
;S. Grzesiek & A. Bax, J. Biomol. NMR 9, 207-211 (1997)
;J.-S. Hu & A. Bax, J. Am. Chem. Soc. 118, 8170-8171 (1996)
;F.A.A. Mulder, R. Otten & R.M. Scheek, J. Biomol. NMR 51,
;   199-207 (2011)
;J. Furrer, F. Kramer, J.P. Marino, S.J. Glaser & B. Luy, J.
;   Magn. Reson. 166, 39-46 (2004)
;I.C. Felli, R. Pierattelli, S.J. Glaser & B. Luy, J. Biomol.
;   NMR 43, 187-196 (2009)
;
; (fm 14/11/13 added additional gradient in SE part for artifact suppression)
; (yy 07/01/14 implemented t1 and t2 evolution as a semi-CT evolution)
; (yy 07/01/14 changed the isotropic mixing scheme from DIPSI3 to MOCCA-XY16)
;
;$CLASS=HighRes
;$DIM=3D
;$TYPE=
;$SUBTYPE=
;$COMMENT=

prosol relations=<triple>

#include <Avance.incl>
#include <Grad.incl>
#include <Delay.incl>

"p2=p1*2"
"p22=p21*2"
"d11=30m"

"d21=5.5m"
"d23=13.5m"
"d26=2.3m"
"d27=d26-d16-p16-4u"

"p17=p16*0.101"

"p9=1.732/(4*(o2-cnst22*bf2/1000000))" ; MOCCA-XY16 pulse length
"plw15=plw2*(pow((p3/p9),2))" ; MOCCA-XY16 power level
"cnst11=d9/p9"
"cnst12=(o2/bf2-cnst22)/(1.732*(cnst11+1))"; Maximum offset (in ppm)
"d31=(p9*2+d9*2)*16*l1"

"d0=3u"
"d10=3u"
"d20=d23+3u"
"d28=3u"
"d29=3u"
"d30=d23+3u"

"in0=inf1/2"
"FACTOR1=d23*10000000*2/td1"
"in20=FACTOR1/10000000"
"in28=larger(in0,in20)-in20"
"in20=in0-in28"

"FACTOR2=d23*10000000*2/td2"
"in10=FACTOR2/10000000"
"in29=larger(inf2/2,in10)-in10"
"in10=inf2/2-in29"
"in30=in10"

"DELTA1=p17+d16+8u"
"DELTA2=d23-d21-p26"
"DELTA3=d23-p22"
"DELTA4=d21-p16-d16-4u"
"DELTA5=d23-d21-p26-p14*2-10u"

"spoff2=0"
"spoff3=0"
"spoff5=bf2*(cnst22/1000000)-o2"
"spoff8=0"

aqseq 321

1 d11 ze
  d11 pl16:f3
2 d11 do:f3
3 d1 pl1:f1 pl2:f2 pl3:f3
  20u UNBLKGRAD
  (center (p3 ph1):f2 (p21 ph1):f3 )
  4u
  p16:gp3
  d16 pl0:f2
  p1 ph1
  d26
  (center (p2 ph1) (p22 ph1):f3 )
  d26
  (p1 ph2):f1

  4u pl0:f1
  (p11:sp1 ph1:r):f1
  4u
  p16:gp1
  d16

  (p21 ph3):f3
  d21 pl19:f1
  (p26 ph2):f1
  DELTA2 cpds1:f1 ph1
  (center (p14:sp3 ph1):f2 (p22 ph1):f3 )
  d23
  (p21 ph1):f3

  4u do:f1
  (p26 ph7):f1
  4u
  p16:gp6
  d16
  (p26 ph2):f1
  4u cpds2:f1 ph1

  (p13:sp2 ph4):f2
  d0
  (p14:sp5 ph1):f2
  DELTA3
  (p22 ph1):f3
  d28
  (p14:sp3 ph1):f2
  d20
  (p14:sp5 ph1):f2
  3u
  (p13:sp8 ph2):f2

  4u do:f1
  (p26 ph7):f1
  4u
  p16:gp7
						;begin MOCCA-XY16
4 d9 pl15:f2
  (p9*2 ph21):f2
  d9*2
  (p9*2 ph22):f2
  d9*2
  (p9*2 ph21):f2
  d9*2
  (p9*2 ph22):f2
  d9*2
  (p9*2 ph22):f2
  d9*2
  (p9*2 ph21):f2
  d9*2
  (p9*2 ph22):f2
  d9*2
  (p9*2 ph21):f2
  d9*2
  (p9*2 ph23):f2
  d9*2
  (p9*2 ph24):f2
  d9*2
  (p9*2 ph23):f2
  d9*2
  (p9*2 ph24):f2
  d9*2
  (p9*2 ph24):f2
  d9*2
  (p9*2 ph23):f2
  d9*2
  (p9*2 ph24):f2
  d9*2
  (p9*2 ph23):f2
  d9
  lo to 4 times l1
						;end MOCCA-XY16
  p16:gp9
  d16 pl0:f2

  (p13:sp2 ph2):f2
  d23
  (center (p14:sp3 ph1):f2 (p22 ph1):f3 )
  d23
  (p13:sp8 ph9):f2

  4u
  p16:gp8
  d16
  (p26 ph2):f1
  4u cpds1:f1 ph1

  (p21 ph1):f3
  d30
  (center (p14:sp5 ph1):f2 (p22 ph1):f3 )
  d29
  (p14:sp3 ph1):f2
  d10
  (p14:sp5 ph1):f2
  d29
  DELTA5
  4u do:f1
  (p26 ph7):f1
  4u
  p16:gp2*EA
  d16
  DELTA4 pl1:f1

  (center (p1 ph1) (p21 ph5):f3 )
  4u
  p16:gp4
  d16
  d27
  (center (p2 ph1) (p22 ph1):f3 )
  4u
  d27
  p16:gp4
  d16
  (center (p1 ph2) (p21 ph6):f3 )
  4u
  p16:gp5
  d16
  d27
  (center (p2 ph1) (p22 ph1):f3 )
  4u
  d27
  p16:gp5
  d16
  (p1 ph1)
  DELTA1
  (p2 ph1)
  4u
  p17:gp2
  d16 pl16:f3
  4u BLKGRAD
  go=2 ph31 cpd3:f3
  d11 do:f3 mc #0 to 2
     F1PH(calph(ph4, +90), caldel(d0, +in0) & caldel(d20, -in20) & caldel(d28, +in28))
     F2EA(calgrad(EA) & calph(ph6, +180), caldel(d10, +in10) & caldel(d29, +in29) & caldel(d30, -in30))
exit

ph1=0
ph2=1
ph3=0 0 0 0 0 0 0 0 2 2 2 2 2 2 2 2
ph4=0 2
ph5=0 0 2 2
ph6=3 3 1 1
ph7=3
ph9=0 0 0 0 2 2 2 2
ph21=0
ph22=1
ph23=2
ph24=3
ph31=0 2 2 0 2 0 0 2 2 0 0 2 0 2 2 0

;pl0 : 0W
;pl1 : f1 channel - power level for pulse (default)
;pl2 : f2 channel - power level for pulse (default)
;pl3 : f3 channel - power level for pulse (default)
;pl15: f2 channel - power level for MOCCA-XY16
;pl16: f3 channel - power level for CPD/BB decoupling
;pl19: f1 channel - power level for CPD/BB decoupling
;sp1: f1 channel - shaped pulse  90 degree  (H2O on resonance)
;sp2: f2 channel - shaped pulse  90 degree  (C=O on resonance)
;sp3: f2 channel - shaped pulse 180 degree  (C=O on resonance)
;sp5: f2 channel - shaped pulse 180 degree  (Ca off resonance)
;sp8: f2 channel - shaped pulse  90 degree  (C=O on resonance)
;                  for time reversed pulse
;p1 : f1 channel -  90 degree high power pulse
;p2 : f1 channel - 180 degree high power pulse
;p3 : f2 channel -  90 degree high power pulse
;p9 : f2 channel -  90 degree low power pulse (MOCCA-XY16)
;p11: f1 channel -  90 degree shaped pulse             [1 msec]
;p13: f2 channel -  90 degree shaped pulse
;p14: f2 channel - 180 degree shaped pulse
;p16: homospoil/gradient pulse                         [1 msec]
;p21: f3 channel -  90 degree high power pulse
;p22: f3 channel - 180 degree high power pulse
;p26: f1 channel -  90 degree pulse at pl19
;d0 : incremented delay (F1 in 3D)
;d1 : relaxation delay; 1-5 * T1
;d9 : delay in MOCCA-XY16 scheme (DELTA/2)
;d10: incremented delay (F2 in 3D)
;d11: delay for disk I/O                               [30 msec]
;d16: delay for homospoil/gradient recovery
;d20: decremented delay (F1 in 3D)
;d21: 1/(2J(NH)                                        [5.5 msec]
;d23: 1/(4J(NCO)                                       [13.5 msec]
;d26: 1/(4J'(NH)                                       [2.3 msec]
;d28: incremented delay (F1 in 3D)
;d29: incremented delay (F2 in 3D)
;d30: decremented delay (F2 in 3D)
;d31: length of MOCCA-XY16 cycle as executed = (p9*2+d9*2)*16*l1
;cnst11: d9/p9
;cnst12: Maximum offset (in ppm)
;cnst21: CO chemical shift (offset, in ppm)
;cnst22: Calpha chemical shift (offset, in ppm)
;o2p: CO chemical shift (cnst21)
;l1: loop for MOCCA-XY16 cycle:
;       mixing time = (p9*2+d9*2)*16*l1
;inf1: 1/SW(CO) = 2 * DW(CO)
;inf2: 1/SW(N) = 2 * DW(N)
;in0: 1/(2 * SW(CO)) = DW(CO)
;nd0: 2
;in10: = d23*2/td2
;nd10: 2
;in20: = d23*2/td1
;in28: = inf1/2-in20
;in29: = inf2/2-in10
;in30: = in10
;ns: 8 * n
;ds: >= 64
;td1: number of experiments in F1  (t1 max > 1/2JNCO)
;td2: number of experiments in F2  (t2 max > 1/2JNCO)
;FnMODE: States-TPPI (or TPPI) in F1
;FnMODE: echo-antiecho in F2
;cpds1: decoupling according to sequence defined by cpdprg1
;cpds2: decoupling according to sequence defined by cpdprg2
;cpd3: decoupling according to sequence defined by cpdprg3
;pcpd1: f1 channel - 90 degree pulse for decoupling sequence
;pcpd2: f1 channel - 90 degree pulse for decoupling sequence
;pcpd3: f3 channel - 90 degree pulse for decoupling sequence

;use gradient ratio:    gp 1 : gp 2 : gp 3 : gp 4 : gp 5 : gp 6 : gp 7 : gp 8 : gp 9
;                         30 :   80 :   24 :   60 :   12 :   20 :   35 :   28 :   45

;for z-only gradients:
;gpz1: 30%
;gpz2: 80%
;gpz3: 24%
;gpz4: 60%
;gpz5: 12%
;gpz6: 20%
;gpz7: 35%
;gpz8: 28%
;gpz9: 45%

;use gradient files:
;gpnam1: SINE.100
;gpnam2: SINE.100
;gpnam3: SINE.100
;gpnam4: SINE.100
;gpnam5: SINE.100
;gpnam6: SINE.100
;gpnam7: SINE.100
;gpnam8: SINE.100
;gpnam9: SINE.100

;$Id: hncocogp3d,v 1.6.6.1 2012/01/31 17:56:27 ber Exp $